POJAZDY Polskie pociagi w 32bpp

[metro]

 .nml  -

Kod:

grf {                                    
    grfid: "oPpK";                        
    name: string(STR_GRF_NAME);            
    desc: string(STR_GRF_DESCRIPTION);     
    version: 0;                            
    min_compatible_version: 0; }    

train_width_32_px = 1;
traininfo_y_offset = 2;
    
template tmpl_sprit_train(x, y) {        
    [ x  ,   y,     10, 30,      -5,-15 ]    
    [ x+ 18 ,y,     28, 28,     -19,-18 ]     
    [ x+ 52 ,y,     42, 18,     -26,-14 ]     
    [ x+ 100,y,     28, 28,     -12,-21 ]     
    [ x+ 136,y,     10, 30,      -3,-18 ]     
    [ x+ 152,y,     28, 28,     -15,-20 ]     
    [ x+ 186,y,     42, 18,     -17,-14 ]    
    [ x+ 234,y,     28, 28,      -7,-18 ] }    
template tmpl_train_zi4(x, y) {            
    [ x,     y,     68,139,     -44,-47 ]     
    [ x+  80,y,    144, 99,    -119,-36 ]     
    [ x+ 240,y,    222, 78,    -164,-55 ]     
    [ x+ 480,y,    144,110,     -87,-72 ]     
    [ x+ 640,y,     68,140,     -44,-88 ]     
    [ x+ 720,y,    144,110,     -75,-70 ]     
    [ x+ 880,y,    222, 78,     -84,-56 ]    
    [ x+1120,y,    144, 99,     -44,-41 ] }    
template templ_sprite_dep(x, y) {        
    [ x,     y,     43, 12,     -20,-10 ] }        
template templ_sprite_dep_zi4(x, y) {    
    [ x,     y,    201, 76,     -67,-67 ] }    
template tmpl_sprit_meni(x, y) {        
    [ x,     y,     44, 12,     -21, -8 ] }    

spriteset(sprity_atrapa, "gfx/atrapa.png")   {
    [ 0,     0,      1,  1,       0,  0 ] }    
spriteset(sprity_vectron_meni, "gfx/vectron.png") {
    tmpl_sprit_meni(4, 60) }    
spriteset(                                
    sprity_vectron_w_depocie                
    , "gfx/vectron.png") { templ_sprite_dep(4, 60) }    
alternative_sprites(                    
    sprity_vectron_w_depocie, ZOOM_LEVEL_IN_4X, BIT_DEPTH_32BPP, "gfx/pkpcargo32.png")
{                                        
    templ_sprite_dep_zi4(34, 2)         
}        
spriteset(sprity_vectron, "gfx/vectron.png") {
    tmpl_sprit_train(4, 20) }     
alternative_sprites(                    
    sprity_vectron, ZOOM_LEVEL_IN_4X, BIT_DEPTH_32BPP, "gfx/pkpcargo00-32.png")
{                                        
    tmpl_train_zi4(18, 8)                
}    
        
switch(FEAT_TRAINS, SELF, sw_vectron_przegubowy, extra_callback_info1) {
    1: return element_vectron;            
    return CB_RESULT_NO_MORE_ARTICULATED_PARTS;
}                                        
switch(FEAT_TRAINS, SELF, sw_vectron_dlugosc , position_in_vehid_chain % 2)  
{                                        
    1: return 5;                        
    return 8;                            
}                                        
switch(FEAT_TRAINS, SELF, sw_vectron_grafiki, position_in_vehid_chain % 2) {
    0: return sprity_vectron;            
    return sprity_atrapa;                
}                                        
switch(FEAT_TRAINS, SELF, sw_vectron_grafiki_w_depocie, position_in_vehid_chain % 2) {
    0: return sprity_vectron_w_depocie;    
    return sprity_atrapa;                
}                                        
switch(FEAT_TRAINS, SELF, sw_sprity_PKPCargo , vehicle_is_in_depot)  
{                                        
    1: sw_vectron_grafiki_w_depocie ;     
    sw_vectron_grafiki ;                  
}                                        
item(FEAT_TRAINS, element_vectron)         
{                                        
    property {                             
        name:                              string(STR_NAME_PKP_CARGO);
        climates_available:                ALL_CLIMATES & ~bitmask(CLIMATE_TOYLAND);            
        introduction_date:                 date(2015, 1, 1);
        model_life:                        VEHICLE_NEVER_EXPIRES;
        vehicle_life:                      25;    
        reliability_decay:                 20;    
        cost_factor:                       35 ;     
        running_cost_factor:               230 ;     
        sprite_id:                         SPRITE_ID_NEW_TRAIN;
        speed:                             200 km/h;
        misc_flags:                        bitmask();
        refit_cost:                        0;    
        track_type:                        RAIL;    
        ai_special_flag:                   AI_FLAG_CARGO;
        power:                             6400 kW;
        running_cost_base:                 RUNNING_COST_ELECTRIC;
        dual_headed:                       0;    
        weight:                            87 ton;
        ai_engine_rank:                    0;     
        engine_class:                      ENGINE_CLASS_ELECTRIC;
        extra_power_per_wagon:             0 kW;
        tractive_effort_coefficient:       0.352;
        air_drag_coefficient:              0.07;
        length:                            8;    
        extra_weight_per_wagon:            0;    
        visual_effect_and_powered:         visual_effect_and_powered(VISUAL_EFFECT_DEFAULT, 0, DISABLE_WAGON_POWER);
        bitmask_vehicle_info:              0;    
    }                                        
    graphics {                            
        purchase:                          sprity_vectron_meni;
        default:                           sw_sprity_PKPCargo;
        articulated_part:                  sw_vectron_przegubowy;
        length:                            sw_vectron_dlugosc;         
    }                                    
}

oraz english.lng i polish.lng (w kolejnych postach)